Something is going wrong

[wquatan]

Tried several times to execute 9.4, but once got at

Code: Select all

Warning: Integrity database ..\client\md\hashes-dotnet-x86-glb.txt not found.
Determining static update urls for dotnet x86-glb...
Extracting Microsoft's update catalog file package.xml...
12:07:50,00 - Determining superseded updates (please be patient, this will take
a while)...

... it stays there for ever.

Even after half an hour or more, nothing moves.

I can see that the ExcludeList-superseded.txt is removed from the exclude-directory, but that's it.

[aker]

Which AV program is installed on the computer?

[wquatan]

I also had AV in mind, so disabled it in above example, and after a very long time (3+ hours) the download finally continued (see time stamps below)

Code: Select all

wo 03/09/2014 12:07:46,42 - Info: Determined static update urls for dotnet x86-glb
wo 03/09/2014 15:24:25,51 - Info: Determined superseded updates

[aker]

Might be caused by AV even if it is disabled...
There are known problems with Microsoft Security Essentials, avast, and a few others.

What happens, if you start a download run using version 9.3.1 in another folder?

@WSUSUpdateAdmin
Könnte dies durch diese Code-Zeilen ausgelöst werden (viele Zugriffe auf eine Datei)?

Code: Select all

1030   for /F "usebackq tokens=1,2 delims=," %%i in ("%TEMP%\UpdateRevisionAndFileIds.txt") do (
1031     if "%%j"=="" (
1032       set REVISION_ID=%%i
1033       echo %%i>>"%TEMP%\BundledUpdateRevisionAndFileIds.txt"
1034     ) else (
1035       echo %%i,%%j;!REVISION_ID!>>"%TEMP%\BundledUpdateRevisionAndFileIds.txt"
1036     )
1037   )



[wquatan]

Under the same circumstances (PC, AV, ....) the difference in 931 is huge and comparable with what I remember since I use WSUSoffline (see comparable timestamps below) :

Code: Select all

wo 03/09/2014 23:00:49,73 - Info: Determined static update urls for dotnet x86-glb
2014-09-03 23:00:53 URL:http://download.wsusoffline.net/ExcludeList-superseded-exclude.txt [190/190] -> "../exclude/ExcludeList-superseded-exclude.txt" [1]
wo 03/09/2014 23:04:43,03 - Info: Determined superseded updates

[aker]

For debugging you need to edit the file .\cmd\DownloadUpdates.cmd (create a backup of the original file).
Replace the lines 1012 to 1072 (wsusou 9.4)

Code: Select all

echo %TIME% - Determining superseded updates (please be patient, this will take a while)...
...
%SystemRoot%\System32\attrib.exe -A ..\client\wsus\wsusscn2.cab


with the following code:

Code: Select all

echo %TIME% - Determining superseded updates (please be patient, this will take a while)...
echo %TIME% - ValidUpdateRevisionIds.txt
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractUpdateRevisionIds.xsl "%TEMP%\ValidUpdateRevisionIds.txt"
if errorlevel 1 goto DownloadError
echo %TIME% - SupersedingRevisionIds.txt
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractSupersedingRevisionIds.xsl "%TEMP%\SupersedingRevisionIds.txt"
if errorlevel 1 goto DownloadError
echo %TIME% - ValidSupersedingRevisionIds.txt
%SystemRoot%\System32\findstr.exe /L /G:"%TEMP%\SupersedingRevisionIds.txt" "%TEMP%\ValidUpdateRevisionIds.txt" >"%TEMP%\ValidSupersedingRevisionIds.txt"
del "%TEMP%\ValidUpdateRevisionIds.txt"
del "%TEMP%\SupersedingRevisionIds.txt"
echo %TIME% - SupersededUpdateRelations.txt
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractSupersededUpdateRelations.xsl "%TEMP%\SupersededUpdateRelations.txt"
if errorlevel 1 goto DownloadError
echo %TIME% - ValidSupersededUpdateRelations.txt
%SystemRoot%\System32\findstr.exe /L /G:"%TEMP%\ValidSupersedingRevisionIds.txt" "%TEMP%\SupersededUpdateRelations.txt" >"%TEMP%\ValidSupersededUpdateRelations.txt"
del "%TEMP%\SupersededUpdateRelations.txt"
del "%TEMP%\ValidSupersedingRevisionIds.txt"
echo %TIME% - ValidSupersededRevisionIds.txt
%CSCRIPT_PATH% //Nologo //B //E:vbs ExtractIdsAndFileNames.vbs "%TEMP%\ValidSupersededUpdateRelations.txt" "%TEMP%\ValidSupersededRevisionIds.txt" /firstonly
del "%TEMP%\ValidSupersededUpdateRelations.txt"
echo %TIME% - UpdateRevisionAndFileIds.txt
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractUpdateRevisionAndFileIds.xsl "%TEMP%\UpdateRevisionAndFileIds.txt"
if errorlevel 1 goto DownloadError
set REVISION_ID=
echo %TIME% - BundledUpdateRevisionAndFileIds.txt
for /F "usebackq tokens=1,2 delims=," %%i in ("%TEMP%\UpdateRevisionAndFileIds.txt") do (
  if "%%j"=="" (
    set REVISION_ID=%%i
    echo %%i>>"%TEMP%\BundledUpdateRevisionAndFileIds.txt"
  ) else (
    echo %%i,%%j;!REVISION_ID!>>"%TEMP%\BundledUpdateRevisionAndFileIds.txt"
  )
)
set REVISION_ID=
del "%TEMP%\UpdateRevisionAndFileIds.txt"
echo %TIME% - SupersededRevisionAndFileIds.txt
%SystemRoot%\System32\findstr.exe /L /G:"%TEMP%\ValidSupersededRevisionIds.txt" "%TEMP%\BundledUpdateRevisionAndFileIds.txt" >"%TEMP%\SupersededRevisionAndFileIds.txt"
del "%TEMP%\ValidSupersededRevisionIds.txt"
del "%TEMP%\BundledUpdateRevisionAndFileIds.txt"
echo %TIME% - SupersededFileIds.txt
%CSCRIPT_PATH% //Nologo //B //E:vbs ExtractIdsAndFileNames.vbs "%TEMP%\SupersededRevisionAndFileIds.txt" "%TEMP%\SupersededFileIds.txt" /secondonly
del "%TEMP%\SupersededRevisionAndFileIds.txt"
echo %TIME% - SupersededFileIdsSorted.txt
%SystemRoot%\System32\sort.exe "%TEMP%\SupersededFileIds.txt" /O "%TEMP%\SupersededFileIdsSorted.txt"
del "%TEMP%\SupersededFileIds.txt"
echo %TIME% - SupersededFileIdsUnique.txt
%CSCRIPT_PATH% //Nologo //B //E:vbs ExtractUniqueFromSorted.vbs "%TEMP%\SupersededFileIdsSorted.txt" "%TEMP%\SupersededFileIdsUnique.txt"
del "%TEMP%\SupersededFileIdsSorted.txt"
echo %TIME% - UpdateCabExeIdsAndLocations.txt
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractUpdateCabExeIdsAndLocations.xsl "%TEMP%\UpdateCabExeIdsAndLocations.txt"
if errorlevel 1 goto DownloadError
echo %TIME% - SupersededCabExeIdsAndLocations.txt
%SystemRoot%\System32\findstr.exe /B /L /G:"%TEMP%\SupersededFileIdsUnique.txt" "%TEMP%\UpdateCabExeIdsAndLocations.txt" >"%TEMP%\SupersededCabExeIdsAndLocations.txt"
del "%TEMP%\UpdateCabExeIdsAndLocations.txt"
del "%TEMP%\SupersededFileIdsUnique.txt"
echo %TIME% - ExcludeList-superseded-all.txt
%CSCRIPT_PATH% //Nologo //B //E:vbs ExtractIdsAndFileNames.vbs "%TEMP%\SupersededCabExeIdsAndLocations.txt" "%TEMP%\ExcludeList-superseded-all.txt" /noids
del "%TEMP%\SupersededCabExeIdsAndLocations.txt"
if exist ..\exclude\ExcludeList-superseded-exclude.txt copy /Y ..\exclude\ExcludeList-superseded-exclude.txt "%TEMP%\ExcludeList-superseded-exclude.txt" >nul
if exist ..\exclude\custom\ExcludeList-superseded-exclude.txt (
  type ..\exclude\custom\ExcludeList-superseded-exclude.txt >>"%TEMP%\ExcludeList-superseded-exclude.txt"
)
if exist "%TEMP%\ExcludeList-superseded-exclude.txt" (
  for %%i in ("%TEMP%\ExcludeList-superseded-exclude.txt") do (
    if %%~zi==0 del %%i
  )
)
if exist "%TEMP%\ExcludeList-superseded-exclude.txt" (
  %SystemRoot%\System32\findstr.exe /L /I /V /G:"%TEMP%\ExcludeList-superseded-exclude.txt" "%TEMP%\ExcludeList-superseded-all.txt" >..\exclude\ExcludeList-superseded.txt
  del "%TEMP%\ExcludeList-superseded-all.txt"
  del "%TEMP%\ExcludeList-superseded-exclude.txt"
) else (
  move /Y "%TEMP%\ExcludeList-superseded-all.txt" ..\exclude\ExcludeList-superseded.txt >nul
)
pause
%SystemRoot%\System32\attrib.exe -A ..\client\wsus\wsusscn2.cab

Be sure to copy the complete code. It starts and ends with the same lines as the original one.

This will print the time after every file wsusou creates while determining superseded updates and will ask you to press a key after it determined the superseded updates.
When it asks you to do so maximize the cmd window and create a screenshot of it and post it here. Then restore the original DownloadUpdates.cmd.

If it just says, "Found valid list of superseded updates", please delete .\exclude\ExcludeList-superseded.txt.

[wquatan]

Please be patient , it's running already approx 1 hour and it seems that it will take again 3+ hours.
For your information : "lines 1012 to 1076" should have been "lines 1012 to 1072"

[aker]

For your information : "lines 1012 to 1076" should have been "lines 1012 to 1072"

Fixed that.

Does it print some additional time stamps?

[wquatan]

Here is the copy-result :

Code: Select all

Determining static update urls for dotnet x86-glb...
Extracting Microsoft's update catalog file package.xml...
18:55:20,09 - Determining superseded updates (please be patient, this will take
a while)...
18:55:20,09 - ValidUpdateRevisionIds.txt
18:55:57,59 - SupersedingRevisionIds.txt
18:56:29,28 - ValidSupersedingRevisionIds.txt
18:56:32,78 - SupersededUpdateRelations.txt
18:57:09,53 - ValidSupersededUpdateRelations.txt
18:57:10,31 - ValidSupersededRevisionIds.txt
18:57:21,03 - UpdateRevisionAndFileIds.txt
18:57:46,70 - BundledUpdateRevisionAndFileIds.txt
22:10:34,84 - SupersededRevisionAndFileIds.txt
22:10:37,96 - SupersededFileIds.txt
22:10:57,82 - SupersededFileIdsSorted.txt
22:10:58,57 - SupersededFileIdsUnique.txt
22:11:12,53 - UpdateCabExeIdsAndLocations.txt
22:11:45,68 - SupersededCabExeIdsAndLocations.txt
22:12:05,34 - ExcludeList-superseded-all.txt
Press any key to continue . . .

[aker]

18:27:30,27 - ValidUpdateRevisionIds.txt
18:27:37,73 - SupersedingRevisionIds.txt
18:27:45,31 - ValidSupersedingRevisionIds.txt
18:27:46,26 - SupersededUpdateRelations.txt
18:27:53,91 - ValidSupersededUpdateRelations.txt
18:27:54,06 - ValidSupersededRevisionIds.txt
18:27:54,22 - UpdateRevisionAndFileIds.txt
18:28:01,91 - BundledUpdateRevisionAndFileIds.txt
18:33:20,06 - SupersededRevisionAndFileIds.txt
18:33:20,80 - SupersededFileIds.txt
18:33:21,48 - SupersededFileIdsSorted.txt
18:33:21,64 - SupersededFileIdsUnique.txt
18:33:22,14 - UpdateCabExeIdsAndLocations.txt
18:33:29,81 - SupersededCabExeIdsAndLocations.txt
18:33:35,26 - ExcludeList-superseded-all.txt

Determining superseded updates takes about 6 minutes on my computer with AV enabled.
That's why I think, that your AV software is slowing down wsusou, while determining the superseded updates.
Try adding exceptions for the wsusou folder and for %temp%. Then try it again.