Determining superseded updates

[Tobi]

Also heute um 10:04 blieb er an besagter Stelle hängen und im Temp-Ordner sind folgende Dateien:

27.02.2016 08:36 739.781 1055FC55B6B540AA90F318D1246F96BA.tmp
27.02.2016 08:36 739.781 34606BD7FE264F4ABA0876057EEEB1FF.tmp
27.02.2016 08:36 52.094 7A1F8A6AB33A45D685234DCF2B3BD2BD.tmp
27.02.2016 08:36 1.813.536 9EE6D6013D8944C89765D02503DAFE17.tmp
27.02.2016 08:36 52.094 A13955B0A1EE4149B2452E390AF0B9C9.tmp
27.02.2016 08:36 1.695.866 A7E54B08E45B472CA75020540A8ABFAD.tmp
27.02.2016 08:48 4.396 AdobeARM.log
03.10.2013 19:36 <DIR> d6806242-f929-48b8-b0ca-554bb9e6b505
27.02.2016 08:36 699.517 E2FC5A15D1D54D72AF7E20D9872505F6.tmp
27.02.2016 08:36 79.958 E53F86ECFFB641E9B8F2F9B71BBDF955.tmp
27.02.2016 08:36 1.813.536 E7BE59265AAF460DAA60A275117AAD91.tmp
27.02.2016 08:36 79.958 EE53D997F0C0444AADBB01436C6022F4.tmp
27.02.2016 08:36 23.036 F81FF95AD2904639BA981FDE9F47246A.tmp
21.09.2013 13:36 0 FXSAPIDebugLogFile.txt
03.10.2013 19:37 0 FXSTIFFDebugLogFile.txt
27.02.2016 08:41 748 jusched.log
26.02.2016 15:15 0 lastChanceDst1456496108590182669487681413603.jar
26.02.2016 17:46 0 lastChanceDst1456505193176114915132532544294.jar
26.02.2016 11:58 <DIR> Low
16.12.2013 18:44 <DIR> OO Software
08.02.2016 20:47 80.765.106 package.xml
09.03.2015 15:15 112 ValidStaticLinks-dotnet-x64-glb.txt

Wohl nichts was weiterhelfen würde?!

[aker]

Es ist insofern schon aufschlussreich, dass noch keine Verarbeitung der package.xml eingesetzt hat.
Bitter in der Datei .\cmd\DownloadUpdates.cmd die Zeile "Determining superseded updates" suchen und bei den folgenden cscript-Befehlen (bis zum Aufruf "%SystemRoot%\system32\attrib.exe -A ..\client\wsus\wsusscn2.cab"; ist ca. 50 Zeilen danach) die Option "//B" entfernen und die Ausgabe erneut posten.

Viele Grüße

[Tobi]

Habe ich gemacht, jetzt sieht die Ausgabe so aus:

17:57:39,96 - Determining superseded updates (please be patient, this will take
a while)...
XSLT uses MSXML 6.0
XSLT uses MSXML 6.0
XSLT uses MSXML 6.0
XSLT uses MSXML 6.0

Steht nach über 20 Minuten immer noch an dieser Stelle.

[aker]

Das bedeutet, das Programm müsste irgendwo hinter dieser Zeile stecken bleiben: "for /F "usebackq tokens=1,2 delims=," %%i in ("%TEMP%\UpdateRevisionAndFileIds.txt") do ("

Welches Änderungsdatum hat denn die Datei .\exclude\ExcludeList-superseded.txt?

Viele Grüße

[Tobi]

Die Datei gibt es bei mir nicht!
Es gibt eine mit dem Namen ExcludeList-superseded-exclude.txt die vom 15.02.16 ist.

[aker]

Eine Kombination aus der Ausgabe & dem Inhalt des %temp%-Ordners sollte eigentlich nicht auftreten. Ich werde in diesen Post gleich noch einmal eine geänderte DownloadUpdates.cmd einstellen, welche noch etwas Debugging gestattet, wenn die jedoch nicht weiterhilft, muss sich WSUSUpdateAdmin diese Situation hier mal ansehen.

Hier ein modifizierter Ausschnitt aus der DownloadUpdates.cmd, bitte den entsprechenden Bereich in der Datei damit ersetzen und beim Hänger wiederum einen Screenshot erstellen.

Code: Select all

rem *** Determine superseded updates ***
for %%i in (..\client\wsus\wsusscn2.cab) do echo %%~ai | %SystemRoot%\System32\find.exe /I "a" >nul 2>&1
if not errorlevel 1 (
  if exist ..\exclude\ExcludeList-superseded.txt del ..\exclude\ExcludeList-superseded.txt
)
copy /Y ..\exclude\ExcludeList-superseded-exclude.txt ..\exclude\ExcludeList-superseded-exclude.ori >nul
%DLDR_PATH% %DLDR_COPT% %DLDR_NVOPT% %DLDR_POPT% ..\exclude %DLDR_LOPT% http://download.wsusoffline.net/ExcludeList-superseded-exclude.txt
echo n | %SystemRoot%\System32\comp.exe ..\exclude\ExcludeList-superseded-exclude.txt ..\exclude\ExcludeList-superseded-exclude.ori /A /L /C >nul 2>&1
if errorlevel 1 (
  if exist ..\exclude\ExcludeList-superseded.txt del ..\exclude\ExcludeList-superseded.txt
)
del ..\exclude\ExcludeList-superseded-exclude.ori
if exist ..\exclude\ExcludeList-superseded.txt (
  echo Found valid list of superseded updates.
  echo %DATE% %TIME% - Info: Found valid list of superseded updates>>%DOWNLOAD_LOGFILE%
  goto SkipSuperseded
)
echo %TIME% - Determining superseded updates (please be patient, this will take a while)...
echo ValidUpdateRevisionIds
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractUpdateRevisionIds.xsl "%TEMP%\ValidUpdateRevisionIds.txt"
if errorlevel 1 goto DownloadError
echo SupersedingRevisionIds
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractSupersedingRevisionIds.xsl "%TEMP%\SupersedingRevisionIds.txt"
if errorlevel 1 goto DownloadError
echo ValidSupersedingRevisionIds
%SystemRoot%\System32\findstr.exe /L /I /G:"%TEMP%\SupersedingRevisionIds.txt" "%TEMP%\ValidUpdateRevisionIds.txt" >"%TEMP%\ValidSupersedingRevisionIds.txt"
del "%TEMP%\ValidUpdateRevisionIds.txt"
del "%TEMP%\SupersedingRevisionIds.txt"
echo SupersededUpdateRelations
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractSupersededUpdateRelations.xsl "%TEMP%\SupersededUpdateRelations.txt"
if errorlevel 1 goto DownloadError
echo ValidSupersededUpdateRelations
%SystemRoot%\System32\findstr.exe /L /I /G:"%TEMP%\ValidSupersedingRevisionIds.txt" "%TEMP%\SupersededUpdateRelations.txt" >"%TEMP%\ValidSupersededUpdateRelations.txt"
del "%TEMP%\SupersededUpdateRelations.txt"
del "%TEMP%\ValidSupersedingRevisionIds.txt"
echo ValidSupersededRevisionIds
%CSCRIPT_PATH% //Nologo //B //E:vbs ExtractIdsAndFileNames.vbs "%TEMP%\ValidSupersededUpdateRelations.txt" "%TEMP%\ValidSupersededRevisionIds.txt" /firstonly
del "%TEMP%\ValidSupersededUpdateRelations.txt"
echo UpdateRevisionAndFileIds
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractUpdateRevisionAndFileIds.xsl "%TEMP%\UpdateRevisionAndFileIds.txt"
if errorlevel 1 goto DownloadError
echo BundledUpdateRevisionAndFileIds
set REVISION_ID=
for /F "usebackq tokens=1,2 delims=," %%i in ("%TEMP%\UpdateRevisionAndFileIds.txt") do (
  if "%%j"=="" (
    set REVISION_ID=%%i
    echo %%i>>"%TEMP%\BundledUpdateRevisionAndFileIds.txt"
  ) else (
    echo %%i,%%j;!REVISION_ID!>>"%TEMP%\BundledUpdateRevisionAndFileIds.txt"
  )
)
set REVISION_ID=
del "%TEMP%\UpdateRevisionAndFileIds.txt"
echo SupersededRevisionAndFileIds
%SystemRoot%\System32\findstr.exe /L /I /G:"%TEMP%\ValidSupersededRevisionIds.txt" "%TEMP%\BundledUpdateRevisionAndFileIds.txt" >"%TEMP%\SupersededRevisionAndFileIds.txt"
del "%TEMP%\ValidSupersededRevisionIds.txt"
del "%TEMP%\BundledUpdateRevisionAndFileIds.txt"
echo SupersededFileIds
%CSCRIPT_PATH% //Nologo //B //E:vbs ExtractIdsAndFileNames.vbs "%TEMP%\SupersededRevisionAndFileIds.txt" "%TEMP%\SupersededFileIds.txt" /secondonly
del "%TEMP%\SupersededRevisionAndFileIds.txt"
echo SupersededFileIdsUnique
..\bin\gsort.exe -u -T "%TEMP%" "%TEMP%\SupersededFileIds.txt" >"%TEMP%\SupersededFileIdsUnique.txt"
del "%TEMP%\SupersededFileIds.txt"
echo UpdateCabExeIdsAndLocations
%CSCRIPT_PATH% //Nologo //B //E:vbs XSLT.vbs "%TEMP%\package.xml" ..\xslt\ExtractUpdateCabExeIdsAndLocations.xsl "%TEMP%\UpdateCabExeIdsAndLocations.txt"
if errorlevel 1 goto DownloadError
echo SupersededCabExeIdsAndLocations
%SystemRoot%\System32\findstr.exe /B /L /I /G:"%TEMP%\SupersededFileIdsUnique.txt" "%TEMP%\UpdateCabExeIdsAndLocations.txt" >"%TEMP%\SupersededCabExeIdsAndLocations.txt"
del "%TEMP%\UpdateCabExeIdsAndLocations.txt"
del "%TEMP%\SupersededFileIdsUnique.txt"
echo ExcludeList-superseded-all
%CSCRIPT_PATH% //Nologo //B //E:vbs ExtractIdsAndFileNames.vbs "%TEMP%\SupersededCabExeIdsAndLocations.txt" "%TEMP%\ExcludeList-superseded-all.txt" /noids
del "%TEMP%\SupersededCabExeIdsAndLocations.txt"
if exist ..\exclude\ExcludeList-superseded-exclude.txt copy /Y ..\exclude\ExcludeList-superseded-exclude.txt "%TEMP%\ExcludeList-superseded-exclude.txt" >nul
if exist ..\exclude\custom\ExcludeList-superseded-exclude.txt (
  type ..\exclude\custom\ExcludeList-superseded-exclude.txt >>"%TEMP%\ExcludeList-superseded-exclude.txt"
)
if exist "%TEMP%\ExcludeList-superseded-exclude.txt" (
  for %%i in ("%TEMP%\ExcludeList-superseded-exclude.txt") do if %%~zi==0 del %%i
)
if exist "%TEMP%\ExcludeList-superseded-exclude.txt" (
  %SystemRoot%\System32\findstr.exe /L /I /V /G:"%TEMP%\ExcludeList-superseded-exclude.txt" "%TEMP%\ExcludeList-superseded-all.txt" >..\exclude\ExcludeList-superseded.txt
  del "%TEMP%\ExcludeList-superseded-all.txt"
  del "%TEMP%\ExcludeList-superseded-exclude.txt"
) else (
  move /Y "%TEMP%\ExcludeList-superseded-all.txt" ..\exclude\ExcludeList-superseded.txt >nul
)
%SystemRoot%\System32\attrib.exe -A ..\client\wsus\wsusscn2.cab
echo %TIME% - Done.


Viele Grüße

[Tobi]

Sorry, aber warum schickst du nicht gleich die Datei bzw. lädst sie (irgendwo zum Download) hoch? Wäre einfacher für mich!

Ich finde den Code zwar teils unter ownloaCore weiß aber nicht ob ich den Abschnitt dort komplett überschreiben soll.
Die Formulierung ist mir etwas zu schwamming!
Habe aber den kompletten Abschnitt (:DownloaCore) jetzt mal überschrieben, wenn das nichts hilft, dann lasse ich es - es gibt noch eine Alternative zu WsusOffline!
Schade halt um die schon erstellten Iso's.

So sieht es im Moment aus:

18:28:34,15 - Determining superseded updates (please be patient, this will take
a while)...
ValidUpdateRevisionIds
SupersedingRevisionIds
ValidSupersedingRevisionIds
SupersededUpdateRelations
ValidSupersededUpdateRelations
ValidSupersededRevisionIds
UpdateRevisionAndFileIds
BundledUpdateRevisionAndFileIds

[aker]

Kann z.Z. nicht hochladen, nur Inhalte posten.
Mein Code war gedacht als Ersatz für die Zeilen 1170-1244 der DownloadUpdates.cmd (WSUSOU 10.5; r740).

Damit ist die Schleife, welche den Hänger auslöst aber identifiziert.
Ein Test noch: die DownloadUpdates.cmd wieder auf das Original zurücksetzen und die folgenden InitializationHook.cmd erstellen (einfach das "t" am Ende von ".cmdt" entfernen):

Code: Select all

set TEMP=D:\wsusou\tmp
set TMP=D:\wsusou\tmp


Statt meines Beispielpfades aber einen verwenden (muss auch existieren), welches in Emsi ausgeschlossen ist.

Das sollte das Problem beheben.

Viele Grüße

[Tobi]

Bringt wohl leider auch nichts!

Habe sogar Wsusoflline 10.5 neu heruntergeladen, entpackt und den Ordner Iso's, samt Dateien, übernommen.
-Eingebunden per net use x: \\vboxsvr\wsusoffline (einmal als User und einmal als Admin)
-Per Explorer x:\wsusoffline\entpackt2 aufgerufen (als User)
-UpdateGenerator.exe gestartet (als User)

Auch probiert per Admin-CMD die UpdateGenerator.exe laufen zu lassen, was klappt, aber er bleibt eben auch an selbiger Stelle hängen.

Langsam die Schnauze voll!!!

[WSUSUpdateAdmin]

Moin!

[...], wenn die jedoch nicht weiterhilft, muss sich WSUSUpdateAdmin diese Situation hier mal ansehen.

Entschuldigung, aber ich habe keine Zeit, mich mit derart exotischen Konfigurationen wie einer per "net use" eingebundenen USB-HDD zu beschäftigen.
Ich käme auch nie auf die Idee, dort das primäre "repository" unterzubringen, sondern würde aus Performanzgründen immer eine lokale Platte nehmen und zum Transport die "copy to target"-Funktionalität nutzen.

Dass die Ursache in dieser Konfiguration liegt oder zumindest damit zusammenhängt, dürfte jedenfalls schon länger klar geworden sein, oder?
Wenn ich neben dem Download noch in drei VMs LiveStream-Videos gucke, ist es eben auch langsamer...

[...], wenn das nichts hilft, dann lasse ich es - es gibt noch eine Alternative zu WsusOffline!

Ja, und das ist doch schön!
Es gibt immer Alternativen - zu Windows, zu Office, zum Autofahren oder zum Partner.
"Alternativlos" ist nicht umsonst das Unwort des Jahres 2010!

Langsam die Schnauze voll!!!

Ich dann auch mal.

GTW